untis, untis-git: rename from timetable, timetable-git

untis/PKGBUILD

@@ -0,0 +1,42 @@
+# Maintainer: Felitendo
+# This PKGBUILD is updated automatically:
+# https://github.com/Felitendo/PKGBUILDS
+
+pkgname=untis
+pkgver=4.3.2
+pkgrel=1
+pkgdesc="GTK4 + LibAdwaita client for WebUntis"
+arch=('any')
+url="https://codeberg.org/ostfriese4/untis"
+license=('GPL-3.0-or-later')
+depends=('gtk4' 'libadwaita' 'webkitgtk-6.0' 'libsecret' 'python'
+         'python-gobject' 'python-cairo' 'python-requests' 'python-pyotp'
+         'glib2' 'hicolor-icon-theme')
+makedepends=('meson' 'ninja' 'glib2-devel' 'gettext')
+# called timetable on the AUR before; same files
+conflicts=('timetable')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('febd90cac783eb1953a3f094c3122b9e47a88e2ae7b8ed33fdc9279300b4505c')
+
+prepare() {
+  # The About dialog reads the version from src/api.py, and upstream does not
+  # always update it for a release (v4.3.2 still says 4.3.1).
+  sed -i "s/^version = \"[^\"]*\"/version = \"$pkgver\"/" untis/src/api.py
+}
+
+build() {
+  meson setup build untis \
+    --prefix=/usr \
+    --buildtype=release \
+    --wrap-mode=nodownload
+  meson compile -C build
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+
+  # generated by pacman hooks; shipping them would cause file conflicts
+  rm -f "$pkgdir/usr/share/glib-2.0/schemas/gschemas.compiled" \
+        "$pkgdir/usr/share/applications/mimeinfo.cache" \
+        "$pkgdir/usr/share/icons/hicolor/icon-theme.cache"
+}